; PGSTE-WATERGATE with balancing gradients

; (16/2/2011 G. ZHENG)

; Gang Zheng, Timothy Stait-Gardner, P.G. Anil Kumar, Allan M. Torres, William S. Price 12 Mar 2008 (Based on Price's idea)

; Gang Zheng, Timothy Stait-Gardner, P.G. Anil Kumar, Allan M. Torres, William S. Price.PGSTE-WATERGATE: An STE-based PGSE

; NMR sequence with excellent solvent suppression.Journal of Magnetic Resonance 191 (2008) 159163

; Gang Zheng and William S Price. Direct hydrodynamic radius measurement on dissolved organic matter in natural waters using

; diffusion NMR. Environmental Science & Technology 46 (2012) 1675-1680.

; for Avance 500

; 1D stimulated spin echo with bipolar gradients for diffusion measurements

; locked version

;

; ALWAYS CHECK cag\_par it should be

; 1.0

; 1.0

; 1.0

; 1.0 0.0 0.0

; 0.0 1.0 0.0

; 0.0 0.0 1.0

#include <Avance.incl>

#include <Grad.incl>

"p2 = p1 \* 2"

"p20 = p16/2"

"d25 = d15-p1/2-50u-p20-d17-50u-d19\*18-p28\*5.95-50u-p20-d17-50u-p1/2-50u-p17-50u-p1/2-2\*d17-p17-p2"

1 ze

 30u

2 d1 pl1:f1

 50u UNBLKGRAD

 p17:gp3\*-1

 d17

 p20:gp1\*-1

 d17

 p20:gp2\*-1

 d17

 50u BLKGRAD

 p1 ph1

 50u UNBLKGRAD

 p20:gp1 ; 1st grad pulse of 1st bpg

 d17 pl18:f1 ; change power to level pl18 for WaterGate

 50u

 p28\*0.087 ph4

 d19\*2

 p28\*0.206 ph4

 d19\*2

 p28\*0.413 ph4

 d19\*2

 p28\*0.778 ph4

 d19\*2

 p28\*1.491 ph4

 d19\*2

 p28\*1.491 ph5

 d19\*2

 p28\*0.778 ph5

 d19\*2

 p28\*0.413 ph5

 d19\*2

 p28\*0.206 ph5

 d19\*2

 p28\*0.087 ph5

 50u pl1:f1 ; change power level back

 p20:gp2 ; 2nd grad pulse of 1st bpg, end of WaterGate

 d17

 50u BLKGRAD

 p1 ph2

 50u UNBLKGRAD

 p17:gp3

 d17

 d25

 p20:gp2

 d17

 p20:gp1

 d17

 50u BLKGRAD

 p1 ph3

 50u UNBLKGRAD

 p20:gp2\*-1

 d17 pl18:f1 ; change power to level pl18 for WaterGate

 50u

 p28\*0.087 ph6

 d19\*2

 p28\*0.206 ph6

 d19\*2

 p28\*0.413 ph6

 d19\*2

 p28\*0.778 ph6

 d19\*2

 p28\*1.491 ph6

 d19\*2

 p28\*1.491 ph7

 d19\*2

 p28\*0.778 ph7

 d19\*2

 p28\*0.413 ph7

 d19\*2

 p28\*0.206 ph7

 d19\*2

 p28\*0.087 ph7

 50u

 p20:gp1\*-1

 d17

 50u BLKGRAD

 go=2 ph31

 wr #0

exit

ph1 = 0 2

ph2 = 0 1 2 3

ph3 = 0 1 2 3

ph4 = 0 0 1 1 2 2 3 3

ph5 = 2 2 3 3 0 0 1 1

ph6 = 0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1

 2 2 2 2 2 2 2 2 3 3 3 3 3 3 3 3

ph7 = 2 2 2 2 2 2 2 2 3 3 3 3 3 3 3 3

 0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1

ph31 = 0 2 2 0 0 2 2 0 2 0 0 2 2 0 0 2

;RF PULSES

;pl1 : f1 channel - power level for pulse (default) usually 2.65 dB

;pl18 : f1 channel - power level for watergate pulse. This value can be calibrated using calcpowlev

;

;p1 : f1 channel - 90 degree high power pulse ~8 us

;p28 : f1 channel - 90 degree low power pulse for watergate (~ 21us)

;DELAYS

;d1 : relaxation delay 1-5 \* T1

;d15 : Captital delta

;d17 : gradient recovery delay (~ 100 us should be enough for high res probe)

;GRADIENTS

;p16: diffusion gradient pulse = little delta [1-8 ms]

; gradient shape is controlled by gpnam1 and gpnam2 (use a square gradient shape)

; gradient amplitude is controlled by gpz1 and gpz2 (gpz1>gpz2)

;

;p17: purge gradient pulse in tau 2 = typically [1-2 ms]

; gradient shape is controlled by gpnam3 (use a square gradient shape)

; gradient amplitude is controlled by gpz3

;SCANS AND PHASE CYCLES

;NS: preferably 8 \* n

;use the au program wp\_diffamp to increment the gradients